用LISP語言自定義AutoCAD命令

AutoLISP語言作為AutoCAD的二次開發(fā)工具，雖然在功能、運(yùn)行速度和保密性等方面比起ARX等工具要遜色一些，但由于它易學(xué)易用，交互性好，靈活性強(qiáng)，對于那些經(jīng)常使用AutoCAD進(jìn)行繪圖的普通用戶來說，不失為一種理想的開發(fā)工具。下面就介紹用AutoLISP語言自定義的幾個AutoCAD繪圖命令，可以起到簡化操作、提高作圖效率的作用。
一、鍵槽尺寸視圖的繪制命令“jct”
在繪制軸、齒輪或帶輪等零件圖時，經(jīng)常需要畫軸上鍵槽處的剖視圖或輪轂鍵槽的端面視圖，比較麻煩；由于鍵槽的尺寸隨軸徑的變化而變化，所以我們可以用LISP程序來實現(xiàn)自動繪圖。加載下面的程序，在命令行中鍵入”jct”并回車，通過人機(jī)交互的形式輸入有關(guān)參數(shù)，可自動完成軸上鍵槽的剖視圖和輪轂鍵槽的端面視圖的繪制。代碼示例如下所示。
(defun C:jct ()
　(setq pt0 (getpoint "\n 請輸入視圖的中心位置點:"))
　(initget 7)
　(setq loop T)
　(while loop
　(setq d (getreal "\n　請輸入鍵槽處的軸徑(12　(if(or (< d 12) (> d 130))
　　　(alert "軸徑數(shù)據(jù)輸入錯誤!\n\n請重新輸入!")
　　　(setq loop nil)
　　　);if
　　);while
　(cond;根據(jù)軸徑檢索鍵槽尺寸
　　((and (> d 12) (<= d 17)) (setq b 5 t1 3.0 t2 2.3));b表示鍵槽的寬度
　　((and (> d 17) (<= d 22)) (setq b 6 t1 3.5 t2 2.8));t1表示軸上鍵槽的深度
　　((and (> d 22) (<= d 30)) (setq b 8 t1 4.0 t2 3.3));t2表示輪轂上鍵槽的高度
　　((and (> d 30) (<= d 38)) (setq b 10 t1 5.0 t2 3.3))
　　((and (> d 38) (<= d 44)) (setq b 12 t1 5.0 t2 3.3))
((and (> d 44) (<= d 50)) (setq b 14 t1 5.5 t2 3.8))
((and (> d 50) (<= d 58)) (setq b 16 t1 6.0 t2 4.3))
((and (> d 58) (<= d 65)) (setq b 18 t1 7.0 t2 4.4))
((and (> d 65) (<= d 75)) (setq b 20 t1 7.5 t2 4.9))
((and (> d 75) (<= d 85)) (setq b 22 t1 9.0 t2 5.4))
((and (> d 85) (<= d 95)) (setq b 25 t1 9.0 t2 5.4))
((and (> d 95) (<= d 110)) (setq b 28 t1 10.0 t2 6.4))
((and (> d 110) (<= d 130)) (setq b 32 t1 11.0 t2 7.4)))
(command "circle" pt0 "d" d)
(command "zoom" "a")
(setq s1 (ssget "l" ))
(setq di (-(* (/ d 2.0) (/ d 2.0)) (* (/ b 2.0) (/ b 2.0)))
　　　　dx (sqrt di)
　　　　dy (/ b 2.0)
　　　　pt1 (list (+ (car pt0) dx) (+ (cadr pt0) dy)))
　(initget "Zc Lc");Zc表示畫軸鍵槽的剖視圖,Lc表示畫輪轂鍵槽的端面視圖
　(setq zrl (getkword "\n 畫軸鍵槽的剖視圖還是輪轂鍵槽的端面視圖(Z/L)?"))
　(if (= zrl "Zc")
　　(progn;計算軸鍵槽上點的坐標(biāo)
　　　(setq pt2 (list (+ (car pt0) (-(/ d 2.0) t1)) (+ (cadr pt0) dy))
　　　　pt3 (polar pt2 (- (/ pi 2.0)) b)
　　　　pt4 (polar pt3 0 (- dx (- (/ d 2.0) t1))))
　　　);progn
　　);if
　(if (= zrl "Lc")
　　(progn;計算輪轂鍵槽上點的坐標(biāo)
　　　(setq pt2 (list (+ (car pt0) (+(/ d 2.0) t2)) (+ (cadr pt0) dy))
　　　　pt3 (polar pt2 (- (/ pi 2.0)) b)
　　　　pt4 (polar pt3 (- pi) (- (+ (/ d 2.0) t2) dx)))
　　　);progn
　　);if
　(command "pline" pt1 pt2 pt3 pt4 "");畫鍵槽
　(setq s2 (ssget "l"))
　(command "layer" "m" 5 "l" "center" 5 "c" 1 5 "")
　(command "ltscale" 8)
　(command "line" (polar pt0 (- pi) (+ (/ d 2.0) 10));畫中心線
　　　　(polar pt0 0 (+ (/ d 2.0) 10)) "")
　(command "line" (polar pt0　(-(/ pi 2.0)) (+ (/ d 2.0) 10))
　　　　(polar pt0 (/ pi 2.0) (+ (/ d 2.0) 10)) "")
　(command "layer" "s" 0 "")　
　(if (= zrl "Zc")
　　(progn
　　　(setq s3 (entsel "\n 請選擇修剪的目標(biāo):"))
　　　(command "trim" s2 "" s3 "");修剪形成鍵槽
　　　(command "hatch" "U" "45" "2" "n" s1 s2 ""));畫軸上鍵槽處剖視圖的剖面線
　　);if
　(if (= zrl "Lc")
　　(progn
　　(setq s4 (entsel "\n 請選擇修剪的目標(biāo):"))
　　(command "trim" s2 "" s4 "");修剪形成鍵槽
　　(command "rotate" s1 s2 "" pt0 90));將輪轂鍵槽的端面視圖旋轉(zhuǎn)90度
　　);if
　);end defun
二、螺紋孔剖視圖的繪制命令“l(fā)wk”
??? 在繪制機(jī)械零件圖時，經(jīng)常要畫螺紋孔的剖視圖，同樣由于螺紋孔的有關(guān)尺寸都隨螺紋的公稱直徑而變化，我們可以用下面的程序自動完成其剖視圖的繪制。加載后在命令行中鍵入“l(fā)wk”并回車，根據(jù)提示輸入相應(yīng)的參數(shù)即可。代碼示例如下所示。
(defun C:lwk()
　(setq pc (osnap (getpoint "\n 輸入螺紋孔端面的中心點:") "near" ))　
　(setq ang (getangle pc "\n 螺紋孔中心線與水平線的夾角:"))
　(initget 7)
　(setq d (getdist "\n 請輸入螺紋孔的公稱直徑(mm):"))
　(cond;根據(jù)螺紋孔的公稱直徑檢索有關(guān)數(shù)據(jù)(以螺紋零件的材料為鋼或青銅為例)
　　((= d 6.0) (setq l1 10 l2 12 d2 4.917));l1表示螺紋深度
　　((= d 8.0) (setq l1 12 l2 16 d2 6.647));l2表示鉆孔深度
　　((= d 10.0) (setq l1 16 l2 20 d2 8.376));d2表示螺紋小徑
　　((= d 12.0) (setq l1 18 l2 22 d2 10.106))
　　((= d 14.0) (setq l1 22 l2 26 d2 11.835))
　　((= d 16.0) (setq l1 24 l2 28 d2 13.835))
　　((= d 18.0) (setq l1 28 l2 34 d2 15.294))
　　((= d 20.0) (setq l1 30 l2 35 d2 17.294))
　　((= d 22.0) (setq l1 32 l2 38 d2 19.294))
　　((= d 24.0) (setq l1 36 l2 42 d2 20.725))
　　((= d 27.0) (setq l1 40 l2 45 d2 23.725))
　　((= d 30.0) (setq l1 44 l2 52 d2 26.211))
　　((= d 36.0) (setq l1 52 l2 60 d2 31.670)))
　(setq r2 (/ d2 2.0);計算光孔各點坐標(biāo)
　　pt1 (polar pc (+ (/ pi 2.0) ang) r2)
　　pt2 (polar pt1 ang l2)
　　pt3 (polar pc ang (+ l2 (* 0.57735 r2)))
　　pt4 (polar pt2 (- ang (/ pi 2.0)) d2)
　　pt5 (polar pc (+ (* pi 1.5) ang) r2))　
　(command "pline" pt1 pt2 pt3 pt4 pt5 "c");畫光孔
　(setq s1 (ssget "l"))
　(command "line" (polar pc (+ pi ang) 3) (polar pt3 ang 3) "");畫中心線
　(command "pline" pt2 pt4 "")
　(setq r1 (/ d 2.0);計算螺紋線的各點坐標(biāo)
　　pt11 (polar pc (+ (/ pi 2.0) ang) r1)
　　pt12 (polar pt11 ang l1)
　　pt13 (polar pt12 (- ang (/ pi 2.0)) d)
　　pt14 (polar pc (+ (* pi 1.5) ang) r1))
　(command "pline" pt11 pt12 pt13 pt14 "");畫螺紋線
　(command "pline" pt12 pt13 "")
　(setq pt21 (polar pc (+ (/ pi 2.0) ang) (+ r1 10.0));計算剖面線邊界上的點坐標(biāo)
　　pt22 (polar pt21 ang (+ l2 15.0));可根據(jù)需要設(shè)置剖面線邊界的大小
　　pt23 (polar pt22 (- ang (/ pi 2.0)) (+ d 20.0))
　　pt24 (polar pc (+ (* pi 1.5) ang) (+ r1 10.0)))
　(command "pline" pt21 pt22 pt23 pt24 "c");生成剖面線的邊界
　(setq s2 (ssget "l"))
　(command "zoom" "a")
　(command "hatch" "U" "45" "2" "n" s2 s1 "");畫剖面線,形成消隱螺紋孔
　);end

三、圓的中心線繪制命令“zxx”
在繪圖中，若需要繪制已知圓的中心線，可調(diào)用下面的程序。加載后在命令行中鍵入“zxx”并回車，只要按提示選擇圓并輸入中心線的延伸長度，即可自動生成該圓的中心線，并可連續(xù)繪制。代碼示例如下所示。
(defun C:zxx()
　(setvar "osmode" 512)
　(setq loop T)
　(while loop
　　(setq pc (getpoint "\n 請用鼠標(biāo)選擇圓:"))
　　(setq s(ssget pc))
　　(if s
　　　(progn
　　(setq s1(entget(ssname s 0))
　　　　　pt0(cdr(assoc 10 s1));獲得圓心坐標(biāo)
　　　　　r (cdr(assoc 40 s1));獲得圓的半徑
　　　　　)
　　(setq l (getreal "\n 請輸入中心線延伸長度(mm):"))
　　(command "layer" "m" 5 "l" "center" 5 "c" 1 5 "")
　(command "ltscale" 8);設(shè)置線型比例
　(command "line" (polar pt0 (- pi) (+ r l));畫中心線
　　 (polar pt0 0 (+ r l)) "")
　(command "line" (polar pt0　(-(/ pi 2.0)) (+ r l))
　　 (polar pt0 (/ pi 2.0) (+ r l)) "")
　(command "layer" "s" 0 "")
　　);progn
　　　(setq loop nil)
　　　);if
　　);while
　);end defun
在繪圖過程中，用戶可根據(jù)需要，用AutoLISP方便地定義出實用的繪圖命令，從而提高繪圖速度。當(dāng)然，還可以將自定義的AutoCAD命令定制成用戶菜單或工具欄,以方便使用。例如，將上面介紹的幾個繪圖命令定制到下拉菜單中的方法是：打開AutoCAD安裝目錄下SUPPORT子目錄中的ACAD.MNU文件，在***POP7項的最后加入下面內(nèi)容，再加載已修改的菜單文件即可。
[--]
ID_User　[鍵槽圖繪制(jct)]^C^C_(if(not jct)(load "d:/Acad R14/jct.lip"));jct;^p
ID_User　[螺紋孔繪制(lwk)]^C^C_(if(not lwk)(load "d:/Acad R14/lwk.lip"));lwk;^p
ID_User　[中心線(zxx)]^C^C_(if(not zxx)(load "d:/Acad R14/zxx.lip"));zxx;^p