利用開源uart2axi4實現(xiàn)串口訪問axi總線
1，引言
圖 1 axi4-lite總線系統(tǒng)
如圖 1所示，《如何簡化axi4-lite slave接口開發(fā)》+《開源axi4_lite_interconnect介紹》介紹了axi4_lite_slave和axi4_lite_interconnect的內(nèi)部結(jié)構(gòu)和原理以及實現(xiàn)方法，這次我們介紹axi4_lite_master主機(jī)uart2axi4，這樣對整個axi4_lite系統(tǒng)框架構(gòu)成和實現(xiàn)就會有個系統(tǒng)性的認(rèn)識。
microblaze和jtag-to-axi（jtag2axi）雖然也提供了訪問axi總線的能力，但是依賴于xilinx平臺。而uart-to-axi（uart2axi4）橋接器并不依賴任何平臺，可以實現(xiàn)跨fpga平臺使用。利用uart2axi4我們可以通過python，輕松訪問axi4_lite_slave寄存器，大大方便fpga工程師進(jìn)行系統(tǒng)調(diào)試和定位bug。
2，uart2axi4
2.1 設(shè)計框架
圖 2 邏輯設(shè)計框架圖
如果想自己設(shè)計可以采樣上面的框架進(jìn)行設(shè)計：
PC端首先需要通過python進(jìn)行封包，請求包(PC→FPGA)采用TLV(type+len+value)格式進(jìn)行封包，type指示讀/寫操作，len指示讀/寫長度，value為寫數(shù)據(jù)。應(yīng)答包(FPGA→PC)，寫應(yīng)答包指示FPGA寫操作完成，讀應(yīng)答包返回讀數(shù)據(jù)指示讀操作完成。
FPGA端uart2axi4需要包含的模塊：uart模塊完成串口數(shù)據(jù)接收和發(fā)送，tx_fifo和rx_fifo完成串口數(shù)據(jù)緩存，uart_parse模塊完成PC封包數(shù)據(jù)的解析，解析出完整一包后通過axi4_timing_gen模塊完成axi4時序產(chǎn)生。
2.2 開源uart2axi4介紹
開源網(wǎng)址：https://github.com/ultraembedded/core_dbg_bridge，該IP的內(nèi)部框圖可以參考圖 2。uart橋接出來的是axi4_full master接口，但是讀，寫突發(fā)長度固定為1，意味著如果寫8個字節(jié)，就會發(fā)起2次突發(fā)，由于uart速度本來就慢，所以這種設(shè)計也是沒有問題的。
數(shù)據(jù)包格式如下：
write操作
write_cmd(0x10) + len(byte為單位，寫數(shù)據(jù)長度) + addr[31:24] + addr[23:16] + addr[15:8] + addr[7:0] + d0[7:0] + d0[15:8] + d0[23:16] + d0[31:24]+ d1[7:0] + d1[15:8] + d1[23:16] + d1[31:24] + ...
注：如果len不是4的整數(shù)倍，則最后一拍會通過strb的mask操作寫入，地址是MSB→LSB,而數(shù)據(jù)是LSB→ MSB，寫操作沒有應(yīng)答包
read操作
read_cmd(0x11) + len(byte為單位，讀數(shù)據(jù)長度) + addr[31:24] + addr[23:16] + addr[15:8] + addr[7:0]
注：返回的數(shù)據(jù)格式為：d0[7:0] + d0[15:8] + d0[23:16] + d0[31:24] + d1[7:0] + d1[15:8] + d1[23:16] + d1[31:24] + ...
該項目還自帶了python程序，可以參考項目給的例子程序進(jìn)行驗證，并且可以很方面的進(jìn)行移植。
圖 3 python例子
2.3 如何使用
為了方便vivado打包時識別成axi接口，dbg_bridge.v修改如下:
//-----------------------------------------------------------------
// UART -> AXI Debug Bridge
// V1.0
// Ultra-Embedded.com
// Copyright 2017-2019
//
// Email: admin@ultra-embedded.com
//
// License: LGPL
//-----------------------------------------------------------------
//
// This source file may be used and distributed without
// restriction provided that this copyright statement is not
// removed from the file and that any derivative work contains
// the original copyright notice and the associated disclaimer.
//
// This source file is free software; you can redistribute it
// and/or modify it under the terms of the GNU Lesser General
// Public License as published by the Free Software Foundation;
// either version 2.1 of the License, or (at your option) any
// later version.
//
// This source is distributed in the hope that it will be
// useful, but WITHOUT ANY WARRANTY; without even the implied
// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
// PURPOSE. See the GNU Lesser General Public License for more
// details.
//
// You should have received a copy of the GNU Lesser General
// Public License along with this source; if not, write to the
// Free Software Foundation, Inc., 59 Temple Place, Suite 330,
// Boston, MA 02111-1307 USA
//-----------------------------------------------------------------
//-----------------------------------------------------------------
// Generated File
//-----------------------------------------------------------------
module dbg_bridge
//-----------------------------------------------------------------
// Params
//-----------------------------------------------------------------
#(
parameter CLK_FREQ = 100_000_000
,parameter UART_SPEED = 115200
//,parameter AXI_ID = 4'd0
,parameter GPIO_ADDRESS = 32'hf0000000
,parameter STS_ADDRESS = 32'hf0000004
)
//-----------------------------------------------------------------
// Ports
//-----------------------------------------------------------------
(
input uart_rxd_i
,output uart_txd_o
,input [ 31:0] gpio_inputs_i
,output [ 31:0] gpio_outputs_o
,input m_axi_aclk
,input m_axi_aresetn
// write cmd
,input m_axi_awready
,output m_axi_awvalid
,output [ 31:0] m_axi_awaddr
,output [ 7:0] m_axi_awlen
//,output [ 3:0] mem_awid_o
,output [ 1:0] m_axi_awburst
// add by user
,output [ 2:0] m_axi_awsize
,output [ 2:0] m_axi_awprot
,output [ 3:0] m_axi_awcache
// write dat
,input m_axi_wready
,output m_axi_wvalid
,output [ 31:0] m_axi_wdata
,output [ 3:0] m_axi_wstrb
,output m_axi_wlast
// write bresp
,output m_axi_bready
,input m_axi_bvalid
,input [ 1:0] m_axi_bresp
//,input [ 3:0] mem_bid_i
// read dat
,input m_axi_rvalid
,output m_axi_rready
,input [ 31:0] m_axi_rdata
,input [ 1:0] m_axi_rresp
//,input [ 3:0] mem_rid_i
,input m_axi_rlast
// read cmd
,input m_axi_arready
,output m_axi_arvalid
,output [ 31:0] m_axi_araddr
//,output [ 3:0] mem_arid_o
,output [ 7:0] m_axi_arlen
,output [ 1:0] m_axi_arburst
// add by user
,output [ 2:0] m_axi_arsize
,output [ 2:0] m_axi_arprot
,output [ 3:0] m_axi_arcache
);
//-----------------------------------------------------------------
// Defines
//-----------------------------------------------------------------
localparam REQ_WRITE = 8'h10;
localparam REQ_READ = 8'h11;
`define STATE_W 4
`define STATE_R 3:0
localparam STATE_IDLE = 4'd0;
localparam STATE_LEN = 4'd2;
localparam STATE_ADDR0 = 4'd3;
localparam STATE_ADDR1 = 4'd4;
localparam STATE_ADDR2 = 4'd5;
localparam STATE_ADDR3 = 4'd6;
localparam STATE_WRITE = 4'd7;
localparam STATE_READ = 4'd8;
localparam STATE_DATA0 = 4'd9;
localparam STATE_DATA1 = 4'd10;
localparam STATE_DATA2 = 4'd11;
localparam STATE_DATA3 = 4'd12;
//-----------------------------------------------------------------
// Wires / Regs
//-----------------------------------------------------------------
wire uart_wr_w;
wire [7:0] uart_wr_data_w;
wire uart_wr_busy_w;
wire uart_rd_w;
wire [7:0] uart_rd_data_w;
wire uart_rd_valid_w;
wire uart_rx_error_w;
wire tx_valid_w;
wire [7:0] tx_data_w;
wire tx_accept_w;
wire read_skip_w;
wire rx_valid_w;
wire [7:0] rx_data_w;
wire rx_accept_w;
reg [31:0] mem_addr_q;
reg mem_busy_q;
reg mem_wr_q;
reg [7:0] len_q;
// Byte Index
reg [1:0] data_idx_q;
// Word storage
reg [31:0] data_q;
wire magic_addr_w = (mem_addr_q == GPIO_ADDRESS || mem_addr_q == STS_ADDRESS);
// add by user
wire clk_i;
wire rst_i;
assign clk_i = m_axi_aclk;
assign rst_i = ~m_axi_aresetn;
//-----------------------------------------------------------------
// UART core
//-----------------------------------------------------------------
dbg_bridge_uart
#( .UART_DIVISOR_W(32) )
u_uart
(
.clk_i(clk_i),
.rst_i(rst_i),
// Control
.bit_div_i((CLK_FREQ / UART_SPEED) - 1),
.stop_bits_i(1'b0), // 0 = 1, 1 = 2
// Transmit
.wr_i(uart_wr_w),
.data_i(uart_wr_data_w),
.tx_busy_o(uart_wr_busy_w),
// Receive
.rd_i(uart_rd_w),
.data_o(uart_rd_data_w),
.rx_ready_o(uart_rd_valid_w),
.rx_err_o(uart_rx_error_w),
// UART pins
.rxd_i(uart_rxd_i),
.txd_o(uart_txd_o)
);
//-----------------------------------------------------------------
// Output FIFO
//-----------------------------------------------------------------
wire uart_tx_pop_w = ~uart_wr_busy_w;
dbg_bridge_fifo
#(
.WIDTH(8),
.DEPTH(8),
.ADDR_W(3)
)
u_fifo_tx
(
.clk_i(clk_i),
.rst_i(rst_i),
// In
.push_i(tx_valid_w),
.data_in_i(tx_data_w),
.accept_o(tx_accept_w),
// Out
.pop_i(uart_tx_pop_w),
.data_out_o(uart_wr_data_w),
.valid_o(uart_wr_w)
);
//-----------------------------------------------------------------
// Input FIFO
//-----------------------------------------------------------------
dbg_bridge_fifo
#(
.WIDTH(8),
.DEPTH(8),
.ADDR_W(3)
)
u_fifo_rx
(
.clk_i(clk_i),
.rst_i(rst_i),
// In
.push_i(uart_rd_valid_w),
.data_in_i(uart_rd_data_w),
.accept_o(uart_rd_w),
// Out
.pop_i(rx_accept_w),
.data_out_o(rx_data_w),
.valid_o(rx_valid_w)
);
//-----------------------------------------------------------------
// States
//-----------------------------------------------------------------
reg [`STATE_R] state_q;
reg [`STATE_R] next_state_r;
always @ *
begin
next_state_r = state_q;
case (next_state_r)
//-------------------------------------------------------------
// IDLE:
//-------------------------------------------------------------
STATE_IDLE:
begin
if (rx_valid_w)
begin
case (rx_data_w)
REQ_WRITE,
REQ_READ:
next_state_r = STATE_LEN;
default:
;
endcase
end
end
//-----------------------------------------
// STATE_LEN
//-----------------------------------------
STATE_LEN :
begin
if (rx_valid_w)
next_state_r = STATE_ADDR0;
end
//-----------------------------------------
// STATE_ADDR
//-----------------------------------------
STATE_ADDR0 : if (rx_valid_w) next_state_r = STATE_ADDR1;
STATE_ADDR1 : if (rx_valid_w) next_state_r = STATE_ADDR2;
STATE_ADDR2 : if (rx_valid_w) next_state_r = STATE_ADDR3;
STATE_ADDR3 :
begin
if (rx_valid_w && mem_wr_q)
next_state_r = STATE_WRITE;
else if (rx_valid_w)
next_state_r = STATE_READ;
end
//-----------------------------------------
// STATE_WRITE
//-----------------------------------------
STATE_WRITE :
begin
if (len_q == 8'b0 && (m_axi_bvalid || magic_addr_w))
next_state_r = STATE_IDLE;
else
next_state_r = STATE_WRITE;
end
//-----------------------------------------
// STATE_READ
//-----------------------------------------
STATE_READ :
begin
// Data ready
if (m_axi_rvalid || magic_addr_w)
next_state_r = STATE_DATA0;
end
//-----------------------------------------
// STATE_DATA
//-----------------------------------------
STATE_DATA0 :
begin
if (read_skip_w)
next_state_r = STATE_DATA1;
else if (tx_accept_w && (len_q == 8'b0))
next_state_r = STATE_IDLE;
else if (tx_accept_w)
next_state_r = STATE_DATA1;
end
STATE_DATA1 :
begin
if (read_skip_w)
next_state_r = STATE_DATA2;
else if (tx_accept_w && (len_q == 8'b0))
next_state_r = STATE_IDLE;
else if (tx_accept_w)
next_state_r = STATE_DATA2;
end
STATE_DATA2 :
begin
if (read_skip_w)
next_state_r = STATE_DATA3;
else if (tx_accept_w && (len_q == 8'b0))
next_state_r = STATE_IDLE;
else if (tx_accept_w)
next_state_r = STATE_DATA3;
end
STATE_DATA3 :
begin
if (tx_accept_w && (len_q != 8'b0))
next_state_r = STATE_READ;
else if (tx_accept_w)
next_state_r = STATE_IDLE;
end
default:
;
endcase
end
// State storage
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
state_q <= STATE_IDLE;
else
state_q <= next_state_r;
//-----------------------------------------------------------------
// RD/WR to and from UART
//-----------------------------------------------------------------
// Write to UART Tx buffer in the following states
assign tx_valid_w = ((state_q == STATE_DATA0) |
(state_q == STATE_DATA1) |
(state_q == STATE_DATA2) |
(state_q == STATE_DATA3)) && !read_skip_w;
// Accept data in the following states
assign rx_accept_w = (state_q == STATE_IDLE) |
(state_q == STATE_LEN) |
(state_q == STATE_ADDR0) |
(state_q == STATE_ADDR1) |
(state_q == STATE_ADDR2) |
(state_q == STATE_ADDR3) |
(state_q == STATE_WRITE && !mem_busy_q);
//-----------------------------------------------------------------
// Capture length
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
len_q <= 8'd0;
else if (state_q == STATE_LEN && rx_valid_w)
len_q[7:0] <= rx_data_w;
else if (state_q == STATE_WRITE && rx_valid_w && !mem_busy_q)
len_q <= len_q - 8'd1;
else if (state_q == STATE_READ && ((mem_busy_q && m_axi_rvalid) || magic_addr_w))
len_q <= len_q - 8'd1;
else if (((state_q == STATE_DATA0) || (state_q == STATE_DATA1) || (state_q == STATE_DATA2)) && (tx_accept_w && !read_skip_w))
len_q <= len_q - 8'd1;
//-----------------------------------------------------------------
// Capture addr
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
mem_addr_q <= 'd0;
else if (state_q == STATE_ADDR0 && rx_valid_w)
mem_addr_q[31:24] <= rx_data_w;
else if (state_q == STATE_ADDR1 && rx_valid_w)
mem_addr_q[23:16] <= rx_data_w;
else if (state_q == STATE_ADDR2 && rx_valid_w)
mem_addr_q[15:8] <= rx_data_w;
else if (state_q == STATE_ADDR3 && rx_valid_w)
mem_addr_q[7:0] <= rx_data_w;
// Address increment on every access issued
else if (state_q == STATE_WRITE && (mem_busy_q && m_axi_bvalid))
mem_addr_q <= {mem_addr_q[31:2], 2'b0} + 'd4;
else if (state_q == STATE_READ && (mem_busy_q && m_axi_rvalid))
mem_addr_q <= {mem_addr_q[31:2], 2'b0} + 'd4;
//-----------------------------------------------------------------
// Data Index
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
data_idx_q <= 2'b0;
else if (state_q == STATE_ADDR3)
data_idx_q <= rx_data_w[1:0];
else if (state_q == STATE_WRITE && rx_valid_w && !mem_busy_q)
data_idx_q <= data_idx_q + 2'd1;
else if (((state_q == STATE_DATA0) || (state_q == STATE_DATA1) || (state_q == STATE_DATA2)) && tx_accept_w && (data_idx_q != 2'b0))
data_idx_q <= data_idx_q - 2'd1;
assign read_skip_w = (data_idx_q != 2'b0);
//-----------------------------------------------------------------
// Data Sample
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
data_q <= 32'b0;
// Write to memory
else if (state_q == STATE_WRITE && rx_valid_w && !mem_busy_q)
begin
case (data_idx_q)
2'd0: data_q[7:0] <= rx_data_w;
2'd1: data_q[15:8] <= rx_data_w;
2'd2: data_q[23:16] <= rx_data_w;
2'd3: data_q[31:24] <= rx_data_w;
endcase
end
// Read from GPIO Input?
else if (state_q == STATE_READ && mem_addr_q == GPIO_ADDRESS)
begin
data_q <= {{(32-32){1'b0}}, gpio_inputs_i};
end
// Read from status register?
else if (state_q == STATE_READ && mem_addr_q == STS_ADDRESS)
data_q <= {16'hcafe, 15'd0, mem_busy_q};
// Read from memory
else if (state_q == STATE_READ && m_axi_rvalid)
data_q <= m_axi_rdata;
// Shift data out (read response -> UART)
else if (((state_q == STATE_DATA0) || (state_q == STATE_DATA1) || (state_q == STATE_DATA2)) && (tx_accept_w || read_skip_w))
data_q <= {8'b0, data_q[31:8]};
assign tx_data_w = data_q[7:0];
assign m_axi_wdata = data_q;
//-----------------------------------------------------------------
// AXI: Write Request
//-----------------------------------------------------------------
reg mem_awvalid_q;
reg mem_awvalid_r;
reg mem_wvalid_q;
reg mem_wvalid_r;
always @ *
begin
mem_awvalid_r = 1'b0;
mem_wvalid_r = 1'b0;
// Hold
if (m_axi_awvalid && !m_axi_awready)
mem_awvalid_r = mem_awvalid_q;
else if (m_axi_awvalid)
mem_awvalid_r = 1'b0;
// Every 4th byte, issue bus access
else if (state_q == STATE_WRITE && rx_valid_w && (data_idx_q == 2'd3 || len_q == 1))
mem_awvalid_r = !magic_addr_w;
// Hold
if (m_axi_wvalid && !m_axi_wready)
mem_wvalid_r = mem_wvalid_q;
else if (m_axi_wvalid)
mem_wvalid_r = 1'b0;
// Every 4th byte, issue bus access
else if (state_q == STATE_WRITE && rx_valid_w && (data_idx_q == 2'd3 || len_q == 1))
mem_wvalid_r = !magic_addr_w;
end
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
begin
mem_awvalid_q <= 1'b0;
mem_wvalid_q <= 1'b0;
end
else
begin
mem_awvalid_q <= mem_awvalid_r;
mem_wvalid_q <= mem_wvalid_r;
end
assign m_axi_awvalid = mem_awvalid_q;
assign m_axi_wvalid = mem_wvalid_q;
assign m_axi_awaddr = {mem_addr_q[31:2], 2'b0};
//assign mem_awid_o = AXI_ID;
assign m_axi_awlen = 8'b0;
assign m_axi_awburst = 2'b01;
assign m_axi_wlast = 1'b1;
assign m_axi_bready = 1'b1;
// add by user
assign m_axi_awsize = 3'b010; // 000:1Byte 001:2Bytes 010:4Bytes 011:8Bytes 100:16Byte 101:32Bytes 110:64Bytes 111:128Bytes
assign m_axi_awprot = 3'b000; // 常規(guī)安全數(shù)據(jù)訪問
assign m_axi_awcache = 4'b0011; // 傳輸屬性
//-----------------------------------------------------------------
// AXI: Read Request
//-----------------------------------------------------------------
reg mem_arvalid_q;
reg mem_arvalid_r;
always @ *
begin
mem_arvalid_r = 1'b0;
// Hold
if (m_axi_arvalid && !m_axi_arready)
mem_arvalid_r = mem_arvalid_q;
else if (m_axi_arvalid)
mem_arvalid_r = 1'b0;
else if (state_q == STATE_READ && !mem_busy_q)
mem_arvalid_r = !magic_addr_w;
end
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
mem_arvalid_q <= 1'b0;
else
mem_arvalid_q <= mem_arvalid_r;
assign m_axi_arvalid = mem_arvalid_q;
assign m_axi_araddr = {mem_addr_q[31:2], 2'b0};
//assign mem_arid_o = AXI_ID;
assign m_axi_arlen = 8'b0;
assign m_axi_arburst = 2'b01;
assign m_axi_rready = 1'b1;
// add by user
assign m_axi_arprot = 3'b000; // 常規(guī)安全數(shù)據(jù)訪問
assign m_axi_arcache = 4'b0011; // 傳輸屬性
assign m_axi_arsize = 3'b010; // 000:1Byte 001:2Bytes 010:4Bytes 011:8Bytes 100:16Byte 101:32Bytes 110:64Bytes 111:128Bytes
//-----------------------------------------------------------------
// Write mask
//-----------------------------------------------------------------
reg [3:0] mem_sel_q;
reg [3:0] mem_sel_r;
always @ *
begin
mem_sel_r = 4'b1111;
case (data_idx_q)
2'd0: mem_sel_r = 4'b0001;
2'd1: mem_sel_r = 4'b0011;
2'd2: mem_sel_r = 4'b0111;
2'd3: mem_sel_r = 4'b1111;
endcase
case (mem_addr_q[1:0])
2'd0: mem_sel_r = mem_sel_r & 4'b1111;
2'd1: mem_sel_r = mem_sel_r & 4'b1110;
2'd2: mem_sel_r = mem_sel_r & 4'b1100;
2'd3: mem_sel_r = mem_sel_r & 4'b1000;
endcase
end
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
mem_sel_q <= 4'b0;
// Idle - reset for read requests
else if (state_q == STATE_IDLE)
mem_sel_q <= 4'b1111;
// Every 4th byte, issue bus access
else if (state_q == STATE_WRITE && rx_valid_w && (data_idx_q == 2'd3 || len_q == 8'd1))
mem_sel_q <= mem_sel_r;
assign m_axi_wstrb = mem_sel_q;
//-----------------------------------------------------------------
// Write enable
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
mem_wr_q <= 1'b0;
else if (state_q == STATE_IDLE && rx_valid_w)
mem_wr_q <= (rx_data_w == REQ_WRITE);
//-----------------------------------------------------------------
// Access in progress
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i == 1'b1)
mem_busy_q <= 1'b0;
else if (m_axi_arvalid || m_axi_awvalid)
mem_busy_q <= 1'b1;
else if (m_axi_bvalid || m_axi_rvalid)
mem_busy_q <= 1'b0;
//-----------------------------------------------------------------
// GPIO Outputs
//-----------------------------------------------------------------
reg gpio_wr_q;
reg [31:0] gpio_output_q;
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
gpio_wr_q <= 1'b0;
else if (mem_addr_q == GPIO_ADDRESS && state_q == STATE_WRITE && rx_valid_w && (data_idx_q == 2'd3 || len_q == 1))
gpio_wr_q <= 1'b1;
else
gpio_wr_q <= 1'b0;
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
gpio_output_q <= 32'h0;
else if (gpio_wr_q)
gpio_output_q <= data_q[31:0];
assign gpio_outputs_o = gpio_output_q;
endmodule
為了方便vivado打包時識別成axi接口，dbg_bridge.v修改如下
//-----------------------------------------------------------------
// UART -> AXI Debug Bridge
// V1.0
// Ultra-Embedded.com
// Copyright 2017-2019
//
// Email: admin@ultra-embedded.com
//
// License: LGPL
//-----------------------------------------------------------------
//
// This source file may be used and distributed without
// restriction provided that this copyright statement is not
// removed from the file and that any derivative work contains
// the original copyright notice and the associated disclaimer.
//
// This source file is free software; you can redistribute it
// and/or modify it under the terms of the GNU Lesser General
// Public License as published by the Free Software Foundation;
// either version 2.1 of the License, or (at your option) any
// later version.
//
// This source is distributed in the hope that it will be
// useful, but WITHOUT ANY WARRANTY; without even the implied
// warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
// PURPOSE. See the GNU Lesser General Public License for more
// details.
//
// You should have received a copy of the GNU Lesser General
// Public License along with this source; if not, write to the
// Free Software Foundation, Inc., 59 Temple Place, Suite 330,
// Boston, MA 02111-1307 USA
//-----------------------------------------------------------------
//-----------------------------------------------------------------
// Generated File
//-----------------------------------------------------------------
module dbg_bridge
//-----------------------------------------------------------------
// Params
//-----------------------------------------------------------------
#(
parameter CLK_FREQ = 100_000_000
,parameter UART_SPEED = 115200
//,parameter AXI_ID = 4'd0
,parameter GPIO_ADDRESS = 32'hf0000000
,parameter STS_ADDRESS = 32'hf0000004
)
//-----------------------------------------------------------------
// Ports
//-----------------------------------------------------------------
(
input uart_rxd_i
,output uart_txd_o
,input [ 31:0] gpio_inputs_i
,output [ 31:0] gpio_outputs_o
,input m_axi_aclk
,input m_axi_aresetn
// write cmd
,input m_axi_awready
,output m_axi_awvalid
,output [ 31:0] m_axi_awaddr
,output [ 7:0] m_axi_awlen
//,output [ 3:0] mem_awid_o
,output [ 1:0] m_axi_awburst
// add by user
,output [ 2:0] m_axi_awsize
,output [ 2:0] m_axi_awprot
,output [ 3:0] m_axi_awcache
// write dat
,input m_axi_wready
,output m_axi_wvalid
,output [ 31:0] m_axi_wdata
,output [ 3:0] m_axi_wstrb
,output m_axi_wlast
// write bresp
,output m_axi_bready
,input m_axi_bvalid
,input [ 1:0] m_axi_bresp
//,input [ 3:0] mem_bid_i
// read dat
,input m_axi_rvalid
,output m_axi_rready
,input [ 31:0] m_axi_rdata
,input [ 1:0] m_axi_rresp
//,input [ 3:0] mem_rid_i
,input m_axi_rlast
// read cmd
,input m_axi_arready
,output m_axi_arvalid
,output [ 31:0] m_axi_araddr
//,output [ 3:0] mem_arid_o
,output [ 7:0] m_axi_arlen
,output [ 1:0] m_axi_arburst
// add by user
,output [ 2:0] m_axi_arsize
,output [ 2:0] m_axi_arprot
,output [ 3:0] m_axi_arcache
);
//-----------------------------------------------------------------
// Defines
//-----------------------------------------------------------------
localparam REQ_WRITE = 8'h10;
localparam REQ_READ = 8'h11;
`define STATE_W 4
`define STATE_R 3:0
localparam STATE_IDLE = 4'd0;
localparam STATE_LEN = 4'd2;
localparam STATE_ADDR0 = 4'd3;
localparam STATE_ADDR1 = 4'd4;
localparam STATE_ADDR2 = 4'd5;
localparam STATE_ADDR3 = 4'd6;
localparam STATE_WRITE = 4'd7;
localparam STATE_READ = 4'd8;
localparam STATE_DATA0 = 4'd9;
localparam STATE_DATA1 = 4'd10;
localparam STATE_DATA2 = 4'd11;
localparam STATE_DATA3 = 4'd12;
//-----------------------------------------------------------------
// Wires / Regs
//-----------------------------------------------------------------
wire uart_wr_w;
wire [7:0] uart_wr_data_w;
wire uart_wr_busy_w;
wire uart_rd_w;
wire [7:0] uart_rd_data_w;
wire uart_rd_valid_w;
wire uart_rx_error_w;
wire tx_valid_w;
wire [7:0] tx_data_w;
wire tx_accept_w;
wire read_skip_w;
wire rx_valid_w;
wire [7:0] rx_data_w;
wire rx_accept_w;
reg [31:0] mem_addr_q;
reg mem_busy_q;
reg mem_wr_q;
reg [7:0] len_q;
// Byte Index
reg [1:0] data_idx_q;
// Word storage
reg [31:0] data_q;
wire magic_addr_w = (mem_addr_q == GPIO_ADDRESS || mem_addr_q == STS_ADDRESS);
// add by user
wire clk_i;
wire rst_i;
assign clk_i = m_axi_aclk;
assign rst_i = ~m_axi_aresetn;
//-----------------------------------------------------------------
// UART core
//-----------------------------------------------------------------
dbg_bridge_uart
#( .UART_DIVISOR_W(32) )
u_uart
(
.clk_i(clk_i),
.rst_i(rst_i),
// Control
.bit_div_i((CLK_FREQ / UART_SPEED) - 1),
.stop_bits_i(1'b0), // 0 = 1, 1 = 2
// Transmit
.wr_i(uart_wr_w),
.data_i(uart_wr_data_w),
.tx_busy_o(uart_wr_busy_w),
// Receive
.rd_i(uart_rd_w),
.data_o(uart_rd_data_w),
.rx_ready_o(uart_rd_valid_w),
.rx_err_o(uart_rx_error_w),
// UART pins
.rxd_i(uart_rxd_i),
.txd_o(uart_txd_o)
);
//-----------------------------------------------------------------
// Output FIFO
//-----------------------------------------------------------------
wire uart_tx_pop_w = ~uart_wr_busy_w;
dbg_bridge_fifo
#(
.WIDTH(8),
.DEPTH(8),
.ADDR_W(3)
)
u_fifo_tx
(
.clk_i(clk_i),
.rst_i(rst_i),
// In
.push_i(tx_valid_w),
.data_in_i(tx_data_w),
.accept_o(tx_accept_w),
// Out
.pop_i(uart_tx_pop_w),
.data_out_o(uart_wr_data_w),
.valid_o(uart_wr_w)
);
//-----------------------------------------------------------------
// Input FIFO
//-----------------------------------------------------------------
dbg_bridge_fifo
#(
.WIDTH(8),
.DEPTH(8),
.ADDR_W(3)
)
u_fifo_rx
(
.clk_i(clk_i),
.rst_i(rst_i),
// In
.push_i(uart_rd_valid_w),
.data_in_i(uart_rd_data_w),
.accept_o(uart_rd_w),
// Out
.pop_i(rx_accept_w),
.data_out_o(rx_data_w),
.valid_o(rx_valid_w)
);
//-----------------------------------------------------------------
// States
//-----------------------------------------------------------------
reg [`STATE_R] state_q;
reg [`STATE_R] next_state_r;
always @ *
begin
next_state_r = state_q;
case (next_state_r)
//-------------------------------------------------------------
// IDLE:
//-------------------------------------------------------------
STATE_IDLE:
begin
if (rx_valid_w)
begin
case (rx_data_w)
REQ_WRITE,
REQ_READ:
next_state_r = STATE_LEN;
default:
;
endcase
end
end
//-----------------------------------------
// STATE_LEN
//-----------------------------------------
STATE_LEN :
begin
if (rx_valid_w)
next_state_r = STATE_ADDR0;
end
//-----------------------------------------
// STATE_ADDR
//-----------------------------------------
STATE_ADDR0 : if (rx_valid_w) next_state_r = STATE_ADDR1;
STATE_ADDR1 : if (rx_valid_w) next_state_r = STATE_ADDR2;
STATE_ADDR2 : if (rx_valid_w) next_state_r = STATE_ADDR3;
STATE_ADDR3 :
begin
if (rx_valid_w && mem_wr_q)
next_state_r = STATE_WRITE;
else if (rx_valid_w)
next_state_r = STATE_READ;
end
//-----------------------------------------
// STATE_WRITE
//-----------------------------------------
STATE_WRITE :
begin
if (len_q == 8'b0 && (m_axi_bvalid || magic_addr_w))
next_state_r = STATE_IDLE;
else
next_state_r = STATE_WRITE;
end
//-----------------------------------------
// STATE_READ
//-----------------------------------------
STATE_READ :
begin
// Data ready
if (m_axi_rvalid || magic_addr_w)
next_state_r = STATE_DATA0;
end
//-----------------------------------------
// STATE_DATA
//-----------------------------------------
STATE_DATA0 :
begin
if (read_skip_w)
next_state_r = STATE_DATA1;
else if (tx_accept_w && (len_q == 8'b0))
next_state_r = STATE_IDLE;
else if (tx_accept_w)
next_state_r = STATE_DATA1;
end
STATE_DATA1 :
begin
if (read_skip_w)
next_state_r = STATE_DATA2;
else if (tx_accept_w && (len_q == 8'b0))
next_state_r = STATE_IDLE;
else if (tx_accept_w)
next_state_r = STATE_DATA2;
end
STATE_DATA2 :
begin
if (read_skip_w)
next_state_r = STATE_DATA3;
else if (tx_accept_w && (len_q == 8'b0))
next_state_r = STATE_IDLE;
else if (tx_accept_w)
next_state_r = STATE_DATA3;
end
STATE_DATA3 :
begin
if (tx_accept_w && (len_q != 8'b0))
next_state_r = STATE_READ;
else if (tx_accept_w)
next_state_r = STATE_IDLE;
end
default:
;
endcase
end
// State storage
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
state_q <= STATE_IDLE;
else
state_q <= next_state_r;
//-----------------------------------------------------------------
// RD/WR to and from UART
//-----------------------------------------------------------------
// Write to UART Tx buffer in the following states
assign tx_valid_w = ((state_q == STATE_DATA0) |
(state_q == STATE_DATA1) |
(state_q == STATE_DATA2) |
(state_q == STATE_DATA3)) && !read_skip_w;
// Accept data in the following states
assign rx_accept_w = (state_q == STATE_IDLE) |
(state_q == STATE_LEN) |
(state_q == STATE_ADDR0) |
(state_q == STATE_ADDR1) |
(state_q == STATE_ADDR2) |
(state_q == STATE_ADDR3) |
(state_q == STATE_WRITE && !mem_busy_q);
//-----------------------------------------------------------------
// Capture length
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
len_q <= 8'd0;
else if (state_q == STATE_LEN && rx_valid_w)
len_q[7:0] <= rx_data_w;
else if (state_q == STATE_WRITE && rx_valid_w && !mem_busy_q)
len_q <= len_q - 8'd1;
else if (state_q == STATE_READ && ((mem_busy_q && m_axi_rvalid) || magic_addr_w))
len_q <= len_q - 8'd1;
else if (((state_q == STATE_DATA0) || (state_q == STATE_DATA1) || (state_q == STATE_DATA2)) && (tx_accept_w && !read_skip_w))
len_q <= len_q - 8'd1;
//-----------------------------------------------------------------
// Capture addr
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
mem_addr_q <= 'd0;
else if (state_q == STATE_ADDR0 && rx_valid_w)
mem_addr_q[31:24] <= rx_data_w;
else if (state_q == STATE_ADDR1 && rx_valid_w)
mem_addr_q[23:16] <= rx_data_w;
else if (state_q == STATE_ADDR2 && rx_valid_w)
mem_addr_q[15:8] <= rx_data_w;
else if (state_q == STATE_ADDR3 && rx_valid_w)
mem_addr_q[7:0] <= rx_data_w;
// Address increment on every access issued
else if (state_q == STATE_WRITE && (mem_busy_q && m_axi_bvalid))
mem_addr_q <= {mem_addr_q[31:2], 2'b0} + 'd4;
else if (state_q == STATE_READ && (mem_busy_q && m_axi_rvalid))
mem_addr_q <= {mem_addr_q[31:2], 2'b0} + 'd4;
//-----------------------------------------------------------------
// Data Index
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
data_idx_q <= 2'b0;
else if (state_q == STATE_ADDR3)
data_idx_q <= rx_data_w[1:0];
else if (state_q == STATE_WRITE && rx_valid_w && !mem_busy_q)
data_idx_q <= data_idx_q + 2'd1;
else if (((state_q == STATE_DATA0) || (state_q == STATE_DATA1) || (state_q == STATE_DATA2)) && tx_accept_w && (data_idx_q != 2'b0))
data_idx_q <= data_idx_q - 2'd1;
assign read_skip_w = (data_idx_q != 2'b0);
//-----------------------------------------------------------------
// Data Sample
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
data_q <= 32'b0;
// Write to memory
else if (state_q == STATE_WRITE && rx_valid_w && !mem_busy_q)
begin
case (data_idx_q)
2'd0: data_q[7:0] <= rx_data_w;
2'd1: data_q[15:8] <= rx_data_w;
2'd2: data_q[23:16] <= rx_data_w;
2'd3: data_q[31:24] <= rx_data_w;
endcase
end
// Read from GPIO Input?
else if (state_q == STATE_READ && mem_addr_q == GPIO_ADDRESS)
begin
data_q <= {{(32-32){1'b0}}, gpio_inputs_i};
end
// Read from status register?
else if (state_q == STATE_READ && mem_addr_q == STS_ADDRESS)
data_q <= {16'hcafe, 15'd0, mem_busy_q};
// Read from memory
else if (state_q == STATE_READ && m_axi_rvalid)
data_q <= m_axi_rdata;
// Shift data out (read response -> UART)
else if (((state_q == STATE_DATA0) || (state_q == STATE_DATA1) || (state_q == STATE_DATA2)) && (tx_accept_w || read_skip_w))
data_q <= {8'b0, data_q[31:8]};
assign tx_data_w = data_q[7:0];
assign m_axi_wdata = data_q;
//-----------------------------------------------------------------
// AXI: Write Request
//-----------------------------------------------------------------
reg mem_awvalid_q;
reg mem_awvalid_r;
reg mem_wvalid_q;
reg mem_wvalid_r;
always @ *
begin
mem_awvalid_r = 1'b0;
mem_wvalid_r = 1'b0;
// Hold
if (m_axi_awvalid && !m_axi_awready)
mem_awvalid_r = mem_awvalid_q;
else if (m_axi_awvalid)
mem_awvalid_r = 1'b0;
// Every 4th byte, issue bus access
else if (state_q == STATE_WRITE && rx_valid_w && (data_idx_q == 2'd3 || len_q == 1))
mem_awvalid_r = !magic_addr_w;
// Hold
if (m_axi_wvalid && !m_axi_wready)
mem_wvalid_r = mem_wvalid_q;
else if (m_axi_wvalid)
mem_wvalid_r = 1'b0;
// Every 4th byte, issue bus access
else if (state_q == STATE_WRITE && rx_valid_w && (data_idx_q == 2'd3 || len_q == 1))
mem_wvalid_r = !magic_addr_w;
end
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
begin
mem_awvalid_q <= 1'b0;
mem_wvalid_q <= 1'b0;
end
else
begin
mem_awvalid_q <= mem_awvalid_r;
mem_wvalid_q <= mem_wvalid_r;
end
assign m_axi_awvalid = mem_awvalid_q;
assign m_axi_wvalid = mem_wvalid_q;
assign m_axi_awaddr = {mem_addr_q[31:2], 2'b0};
//assign mem_awid_o = AXI_ID;
assign m_axi_awlen = 8'b0;
assign m_axi_awburst = 2'b01;
assign m_axi_wlast = 1'b1;
assign m_axi_bready = 1'b1;
// add by user
assign m_axi_awsize = 3'b010; // 000:1Byte 001:2Bytes 010:4Bytes 011:8Bytes 100:16Byte 101:32Bytes 110:64Bytes 111:128Bytes
assign m_axi_awprot = 3'b000; // 常規(guī)安全數(shù)據(jù)訪問
assign m_axi_awcache = 4'b0011; // 傳輸屬性
//-----------------------------------------------------------------
// AXI: Read Request
//-----------------------------------------------------------------
reg mem_arvalid_q;
reg mem_arvalid_r;
always @ *
begin
mem_arvalid_r = 1'b0;
// Hold
if (m_axi_arvalid && !m_axi_arready)
mem_arvalid_r = mem_arvalid_q;
else if (m_axi_arvalid)
mem_arvalid_r = 1'b0;
else if (state_q == STATE_READ && !mem_busy_q)
mem_arvalid_r = !magic_addr_w;
end
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
mem_arvalid_q <= 1'b0;
else
mem_arvalid_q <= mem_arvalid_r;
assign m_axi_arvalid = mem_arvalid_q;
assign m_axi_araddr = {mem_addr_q[31:2], 2'b0};
//assign mem_arid_o = AXI_ID;
assign m_axi_arlen = 8'b0;
assign m_axi_arburst = 2'b01;
assign m_axi_rready = 1'b1;
// add by user
assign m_axi_arprot = 3'b000; // 常規(guī)安全數(shù)據(jù)訪問
assign m_axi_arcache = 4'b0011; // 傳輸屬性
assign m_axi_arsize = 3'b010; // 000:1Byte 001:2Bytes 010:4Bytes 011:8Bytes 100:16Byte 101:32Bytes 110:64Bytes 111:128Bytes
//-----------------------------------------------------------------
// Write mask
//-----------------------------------------------------------------
reg [3:0] mem_sel_q;
reg [3:0] mem_sel_r;
always @ *
begin
mem_sel_r = 4'b1111;
case (data_idx_q)
2'd0: mem_sel_r = 4'b0001;
2'd1: mem_sel_r = 4'b0011;
2'd2: mem_sel_r = 4'b0111;
2'd3: mem_sel_r = 4'b1111;
endcase
case (mem_addr_q[1:0])
2'd0: mem_sel_r = mem_sel_r & 4'b1111;
2'd1: mem_sel_r = mem_sel_r & 4'b1110;
2'd2: mem_sel_r = mem_sel_r & 4'b1100;
2'd3: mem_sel_r = mem_sel_r & 4'b1000;
endcase
end
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
mem_sel_q <= 4'b0;
// Idle - reset for read requests
else if (state_q == STATE_IDLE)
mem_sel_q <= 4'b1111;
// Every 4th byte, issue bus access
else if (state_q == STATE_WRITE && rx_valid_w && (data_idx_q == 2'd3 || len_q == 8'd1))
mem_sel_q <= mem_sel_r;
assign m_axi_wstrb = mem_sel_q;
//-----------------------------------------------------------------
// Write enable
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
mem_wr_q <= 1'b0;
else if (state_q == STATE_IDLE && rx_valid_w)
mem_wr_q <= (rx_data_w == REQ_WRITE);
//-----------------------------------------------------------------
// Access in progress
//-----------------------------------------------------------------
always @ (posedge clk_i or posedge rst_i)
if (rst_i == 1'b1)
mem_busy_q <= 1'b0;
else if (m_axi_arvalid || m_axi_awvalid)
mem_busy_q <= 1'b1;
else if (m_axi_bvalid || m_axi_rvalid)
mem_busy_q <= 1'b0;
//-----------------------------------------------------------------
// GPIO Outputs
//-----------------------------------------------------------------
reg gpio_wr_q;
reg [31:0] gpio_output_q;
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
gpio_wr_q <= 1'b0;
else if (mem_addr_q == GPIO_ADDRESS && state_q == STATE_WRITE && rx_valid_w && (data_idx_q == 2'd3 || len_q == 1))
gpio_wr_q <= 1'b1;
else
gpio_wr_q <= 1'b0;
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
gpio_output_q <= 32'h0;
else if (gpio_wr_q)
gpio_output_q <= data_q[31:0];
assign gpio_outputs_o = gpio_output_q;
endmodule
為了方便仿真，dbg_bridge_uart.v修改如下：
//-----------------------------------------------------------------
// UART Tx Pin (change by user :下面的代碼仿真有問題，進(jìn)行了修改)
//-----------------------------------------------------------------
/*reg txd_r;
always @ *
begin
txd_r = 1'b1;
if (tx_busy_q)
begin
// Start bit (TXD = L)
if (tx_bits_q == START_BIT)
txd_r = 1'b0;
// Stop bits (TXD = H)
else if (tx_bits_q == STOP_BIT0 || tx_bits_q == STOP_BIT1)
txd_r = 1'b1;
// Data bits
else
txd_r = tx_shift_reg_q[0];
end
end*/
always @ (posedge clk_i or posedge rst_i)
if (rst_i)
txd_q <= 1'b1;
else
begin
if (tx_busy_q)
begin
// Start bit (TXD = L)
if (tx_bits_q == START_BIT)
txd_q <= 1'b0;
// Stop bits (TXD = H)
else if (tx_bits_q == STOP_BIT0 || tx_bits_q == STOP_BIT1)
txd_q <= 1'b1;
// Data bits
else
txd_q <= tx_shift_reg_q[0];
end
else
txd_q <= 1'b1; ? ??
end
由于IP轉(zhuǎn)換出來的是axi4_full接口，如果是用vivado環(huán)境，可以直接連接到xilinx的axi interconnect，前面文檔介紹過xilinx的互聯(lián)具有協(xié)議轉(zhuǎn)換功能，可以自動轉(zhuǎn)換成axi4_lite接口。如果是非xilinx平臺，我們也是有辦法的，該IP的axi4_full接口，由于設(shè)計突發(fā)長度為1，我們也可以很方便的連接axi4_lite_slave，只需要用到axi4_lite相關(guān)信號，如下圖所示：
圖 4 axi4_lite接口例化示意
python也是很方便的進(jìn)行移植，控制axi_lite_slave寄存器，例子如下：
圖 5 python操作axi_lite_slave寄存器
3，總結(jié)
本文主要介紹axi4_lite_master主機(jī)uart2axi4，利用開源uart2axi4我們可以通過python，輕松訪問axi4_lite_slave寄存器，大大方便fpga工程師進(jìn)行系統(tǒng)調(diào)試和定位bug。
-
寄存器
+關(guān)注
關(guān)注
31文章
5588瀏覽量
128994 -
接口
+關(guān)注
關(guān)注
33文章
9441瀏覽量
156076 -
串口
+關(guān)注
關(guān)注
15文章
1606瀏覽量
81875 -
AXI總線
+關(guān)注
關(guān)注
0文章
68瀏覽量
14713
原文標(biāo)題：利用開源uart2axi4實現(xiàn)串口訪問axi總線
文章出處：【微信號：gh_9d70b445f494，微信公眾號：FPGA設(shè)計論壇】歡迎添加關(guān)注！文章轉(zhuǎn)載請注明出處。
發(fā)布評論請先 登錄
Zynq中AXI4-Lite和AXI-Stream功能介紹
Xilinx zynq AXI總線全面解讀
看看在SpinalHDL中AXI4總線互聯(lián)IP的設(shè)計
AXI 總線和引腳的介紹
一文詳解ZYNQ中的DMA與AXI4總線
ZYNQ中DMA與AXI4總線
深入AXI4總線一握手機(jī)制
AMBA 3.0 AXI總線接口協(xié)議的研究與應(yīng)用
串口轉(zhuǎn)axi主機(jī)總線接口
AXI4 、 AXI4-Lite 、AXI4-Stream接口
Xilinx FPGA AXI4總線（一）介紹【AXI4】【AXI4-Lite】【AXI-Stream】
AXI實戰(zhàn)(二)-AXI-Lite的Slave實現(xiàn)介紹
基于AXI總線的DDR3讀寫測試
工商網(wǎng)監(jiān)
評論